参考資料は、ＣＯＭＥＴⅡの理解を助けるため又はＣＯＭＥＴⅡの処理系作成者に対する 便宜のための資料である。したがって、ＣＯＭＥＴⅡ、ＣＡＳＬⅡの仕様に影響を与えるものではない。

　命令語の構成は定義しないが、次のような構成を想定する。ここで、ＯＰの数値は１６進表示で示す。

15

0

15

0

←ビット番号

第１語				第２語	命令語長	命令語とアセンブラとの対応
ＯＰ		ｒ／ｒ１	ｘ／ｒ２	ａｄｒ		機械語命令		意味
主ＯＰ	副ＯＰ
０	０	−	−	−	１	ＮＯＰ		no operation
１	０ １ ２ ４			−	２ ２ ２ １	ＬＤ ＳＴ ＬＡＤ ＬＤ	ｒ，ａｄｒ，ｘ ｒ，ａｄｒ，ｘ ｒ，ａｄｒ，ｘ ｒ１，ｒ２	load store load address load
２	０ １ ２ ３ ４ ５ ６ ７			− − − −	２ ２ ２ ２ １ １ １ １	ＡＤＤＡ ＳＵＢＡ ＡＤＤＬ ＳＵＢＬ ＡＤＤＡ ＳＵＢＡ ＡＤＤＬ ＳＵＢＬ	ｒ，ａｄｒ，ｘ ｒ，ａｄｒ，ｘ ｒ，ａｄｒ，ｘ ｒ，ａｄｒ，ｘ ｒ１，ｒ２ ｒ１，ｒ２ ｒ１，ｒ２ ｒ１，ｒ２	add arithmetic subtract arithmetic add logical subtract logical add arithmetic subtract arithmetic add logical subtract logical
３	０ １ ２ ４ ５ ６			− − −	２ ２ ２ １ １ １	ＡＮＤ ＯＲ ＸＯＲ ＡＮＤ ＯＲ ＸＯＲ	ｒ，ａｄｒ，ｘ ｒ，ａｄｒ，ｘ ｒ，ａｄｒ，ｘ ｒ１，ｒ２ ｒ１，ｒ２ ｒ１，ｒ２	and or exclusive or and or exclusive or
４	０ １ ４ ５			− −	２ ２ １ １	ＣＰＡ ＣＰＬ ＣＰＡ ＣＰＬ	ｒ，ａｄｒ，ｘ ｒ，ａｄｒ，ｘ ｒ１，ｒ２ ｒ１，ｒ２	compare arithmetic compare logical compare arithmetic compare logical
５	０ １ ２ ３				２ ２ ２ ２	ＳＬＡ ＳＲＡ ＳＬＬ ＳＲＬ	ｒ，ａｄｒ，ｘ ｒ，ａｄｒ，ｘ ｒ，ａｄｒ，ｘ ｒ，ａｄｒ，ｘ	shift left arithmetic shift right arithmetic shift left logical shift right logical
６	１ ２ ３ ４ ５ ６	− − − − − −			２ ２ ２ ２ ２ ２	ＪＭＩ ＪＮＺ ＪＺＥ ＪＵＭＰ ＪＰＬ ＪＯＶ	ａｄｒ，ｘ ａｄｒ，ｘ ａｄｒ，ｘ ａｄｒ，ｘ ａｄｒ，ｘ ａｄｒ，ｘ	jump on minus jump on non zero jump on zero unconditional jump jump on plus jump on overflow
７	０ １	−	−	−	２ １	ＰＵＳＨ ＰＯＰ	ａｄｒ，ｘ ｒ	push pop
８	０ １	− −	−	−	２ １	ＣＡＬＬ ＲＥＴ	ａｄｒ，ｘ	call subroutine return from subroutine
９ ・ ・ Ｅ						その他の命令
Ｆ	０	−			２	ＳＶＣ	ａｄｒ，ｘ	supervisor call

　マクロ命令が生成する命令群は定義しない（語数不定）が、 次の例のような命令群を生成することを想定する。

［例］ＩＮ命令

	LABEL	IN	IBUF,LEN
		　　↓
		マクロ生成
		　　↓
	LABEL	PUSH	0,GR1
		PUSH	0,GR2
		LAD	GR1,IBUF
		LAD	GR2,LEN
		SVC	1
		POP	GR2
		POP	GR1

　シフト演算命令において、たとえば、ビットのシフトをした時の 動き及びＯＦの変化は、次のとおりである。

1. 算術左シフトでは、ビット番号１４の値が設定される。

   15	14	13	12	11	10	9	8	7	6	5	4	3	2	1	0
   符号	↓	←	←	←	←	←	←	←	←	←	←	←	←	←	←	←	０
   	↓
   	ＯＦ

   
   
2. 算術右シフトでは、ビット番号０の値が設定される。

   15	14	13	12	11	10	9	8	7	6	5	4	3	2	1	0
   符号	→	→	→	→	→	→	→	→	→	→	→	→	→	→	→	→	ＯＦ

   
   
3. 論理左シフトでは、ビット番号１５の値が設定される。

   15	14	13	12	11	10	9	8	7	6	5	4	3	2	1	0
   ↓	←	←	←	←	←	←	←	←	←	←	←	←	←	←	←	←	０
   ↓
   ＯＦ

   
   
4. 論理右シフトでは、ビット番号０の値が設定される。

   		15	14	13	12	11	10	9	8	7	6	5	4	3	2	1	0
   ０	→	→	→	→	→	→	→	→	→	→	→	→	→	→	→	→	→	→	ＯＦ

   
   

COUNT1	START			;
;	入力	GR1:検索する語
;	処理	GR1中の'1'のビットの個数を求める
;	出力	GR0:GR1中の'1'のビットの個数
COUNT1	PUSH	0, GR1		;レジスタの値をスタックに退避
	PUSH	0, GR2		;
	SUBA	GR2, GR2		; Count = 0
	AND	GR1, GR1		; 全部のビットが'0'？
	JZE	RETURN		; 全部のビットが'0'なら終了
MORE	LAD	GR2,  1, GR2	; Count = Count +1
	LAD	GR0, -1, GR1	; 最下位の'1'のビット1個を
	AND	GR1, GR0		;  '0'に変える
	JNZ	MORE		; '1'のビットが残っていれば繰り返し
RETURN	LD	GR0, GR2		; GR0 = Count
	POP	GR2		;レジスタの値を復帰させる
	POP	GR1		;
	RET			; 呼び出しプログラムへ戻る
	END			;